MAKE_MASS_MATRIX.f90

Go to the documentation of this file.

!    Copyright (C) 2012 The SPEED FOUNDATION
!    Author: Ilario Mazzieri
!
!    This file is part of SPEED.
!
!    SPEED is free software; you can redistribute it and/or modify it
!    under the terms of the GNU Affero General Public License as
!    published by the Free Software Foundation, either version 3 of the
!    License, or (at your option) any later version.
!
!    SPEED is distributed in the hope that it will be useful, but
!    WITHOUT ANY WARRANTY; without even the implied warranty of
!    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
!    Affero General Public License for more details.
!
!    You should have received a copy of the GNU Affero General Public License
!    along with SPEED.  If not, see <http://www.gnu.org/licenses/>.
 
 
      subroutine make_mass_matrix(nn,xq,wq,dd,rho,&
                           AA11,AA12,AA13,AA21,AA22,AA23,&
                           AA31,AA32,AA33,BB11,BB12,BB13,&
                           BB21,BB22,BB23,BB31,BB32,BB33,&
                           GG1,GG2,GG3,DD1,DD2,DD3,&
                           mass)
      
      
      implicit none
      
      integer*4 :: nn
      integer*4 :: i,j,k
 
      real*8 :: aa11,aa12,aa13,aa21,aa22,aa23,aa31,aa32,aa33
      real*8 :: bb11,bb12,bb13,bb21,bb22,bb23,bb31,bb32,bb33
      real*8 :: gg1,gg2,gg3,dd1,dd2,dd3
      real*8 :: dxdx,dxdy,dxdz,dydx,dydy,dydz,dzdx,dzdy,dzdz,det_j
 
      real*8, dimension(nn) :: xq, wq
 
      real*8, dimension(nn,nn) :: dd
 
      real*8, dimension(nn,nn,nn) :: rho 
      real*8, dimension(nn,nn,nn) :: mass
      
      
!     ELEMENT NODAL MASS CALCULATION
      
      do k = 1,nn
         do j = 1,nn
            do i = 1,nn
               dxdx = aa11 + bb12*xq(k) + bb13*xq(j) + gg1*xq(j)*xq(k)
               dydx = aa21 + bb22*xq(k) + bb23*xq(j) + gg2*xq(j)*xq(k)
               dzdx = aa31 + bb32*xq(k) + bb33*xq(j) + gg3*xq(j)*xq(k)
               
               dxdy = aa12 + bb11*xq(k) + bb13*xq(i) + gg1*xq(k)*xq(i)
               dydy = aa22 + bb21*xq(k) + bb23*xq(i) + gg2*xq(k)*xq(i)
               dzdy = aa32 + bb31*xq(k) + bb33*xq(i) + gg3*xq(k)*xq(i)
               
               dxdz = aa13 + bb11*xq(j) + bb12*xq(i) + gg1*xq(i)*xq(j)
               dydz = aa23 + bb21*xq(j) + bb22*xq(i) + gg2*xq(i)*xq(j)
               dzdz = aa33 + bb31*xq(j) + bb32*xq(i) + gg3*xq(i)*xq(j)
               
               det_j = dxdz * (dydx*dzdy - dzdx*dydy) &
                     - dydz * (dxdx*dzdy - dzdx*dxdy) &
                     + dzdz * (dxdx*dydy - dydx*dxdy)
               
               mass(i,j,k) = rho(i,j,k) * det_j * wq(i)*wq(j)*wq(k)
            enddo
         enddo
      enddo
      
      return
      
      end subroutine make_mass_matrix